# set terminal canvas  rounded size 600,400 enhanced fsize 10 lw 1.6 fontscale 1 name "margins_1" jsdir "."
# set output 'margins.1.js'
unset key
set view map scale 1
set samples 50, 50
set isosamples 50, 50
set style data lines
unset ytics
set urange [ -15.0000 : 15.0000 ] noreverse
set vrange [ -15.0000 : 15.0000 ] noreverse
set xrange [ -15.0000 : 15.0000 ] noreverse
set zrange [ -0.250000 : 1.00000 ] noreverse
set lmargin at screen 0.2
set bmargin at screen 0.1
set rmargin at screen 0.85
set tmargin at screen 0.25
f(h) = sin(sqrt(h**2))/sqrt(h**2)
y = 0
## Last plot was a multiplot
# saved multiplot
set multiplot title "Demo of placing multiple plots (2D and 3D)\nwith explicit alignment of plot borders"
set lmargin at screen 0.20
set rmargin at screen 0.85
set bmargin at screen 0.25
set tmargin at screen 0.85
set pm3d
set palette rgbformulae 7, 5, 15
set view map
set samples 50, 50
set isosamples 50, 50
unset surface
set xrange [ -15.00 : 15.00 ]
set yrange [ -15.00 : 15.00 ]
set zrange [ -0.250 : 1.000 ]
unset xtics
unset ytics
unset key
splot sin(sqrt(x**2+y**2))/sqrt(x**2+y**2)
unset pm3d
unset key
set lmargin at screen 0.10
set rmargin at screen 0.20
set ytics
set parametric
set dummy u,v
set view map
f(h) = sin(sqrt(h**2))/sqrt(h**2)
set urange [ -15.00 : 15.00 ]
set vrange [ -15.00 : 15.00 ]
set xrange [*:*]
set surface
splot f(u), u, 0 with lines lc rgb "green"
unset parametric
set lmargin at screen 0.20
set rmargin at screen 0.85
set bmargin at screen 0.10
set tmargin at screen 0.25
set xrange [ -15.00 : 15.00 ]
set yrange [ * : * ]
set xtics
unset ytics
y = 0
plot sin(sqrt(x**2+y**2))/sqrt(x**2+y**2)
unset multiplot